The Planets in Our Solar System

/*****************************************************/
/*****************************************************/
/**                                                 **/
/** A Program to Demonstrate SAS HTML Capabilitites **/
/**           Using the Planets Data Set            **/
/**                                                 **/
/**                I.  List Reports                 **/
/**                                                 **/
/**        Created by Christine R. Riddiough        **/
/**                     May 2000                    **/
/**                                                 **/
/*****************************************************/
/*****************************************************/

/*****************************************************/
/* Part 1. Create a new style named                  */
/* STYlES.NEWDOC by making changes to                */
/* the StatDoc style. What follows                   */
/* is the StatDoc template modified                  */
/*****************************************************/

proc template;
    define style Styles.NEWDOC;
      parent = styles.StatDoc;
   replace fonts /
      'SASTitleFont' = ("Verdana, Helvetica, Helv",2,Bold Italic)
      'TitleFont2' = ("Verdana, Helvetica, Helv",2,Bold Italic)
      'TitleFont' = ("Verdana, Helvetica, Helv",2,Bold Italic)
      'StrongFont' = ("Verdana, Helvetica, Helv",2,Bold Italic)
      'EmphasisFont' = ("Verdana, Helvetica, Helv",2,Italic)
      'FixedEmphasisFont' = ("Courier New, Courier",2,Italic)
      'FixedStrongFont' = ("Courier New, Courier",2,Bold)
      'FixedHeadingFont' = ("Courier New, Courier",2,Bold)
      'FixedFont' = ("Courier New, Courier",2)
      'headingEmphasisFont' = ("Verdana, Helvetica, Helv",2,Bold Italic)
      'headingFont' = ("Verdana, Helvetica, Helv",2,Bold)
      'docFont' = ("Verdana, Helvetica, Helv",2);
   replace colors /
      'contentbg' = cxB0B0B0
      'contentfg' = cx0033AA
      'link2' = cx0066AA
      'link1' = cx004488
      'bg5' = cxE0E0E0
      'bg4' = cx004488
      'fg4' = cx0066AA
      'bg3' = cxDEDDED
      'fg3' = cx151219
      'bg2' = cxEBDDED 
      'fg2' = cx151219
      'fg' = cx191719;
   replace Container;
   replace Index from Container /
      foreground = colors('fg');
   replace Contents from Document /
      bullet = "decimal"
      pagebreakhtml = html('break')
      background = colors('bg2')
      leftmargin = 8;
   replace Pages from Document /
      bullet = "decimal"
      pagebreakhtml = html('break')
      background = colors('bg2')
      leftmargin = 8;
   replace Date from Container /
      outputwidth = 100%
      foreground = colors('fg3');
   replace BodyDate from Date;
   replace IndexItem from Container /
      prehtml = html('fake bullet')
      listentryanchor = on
      bullet = NONE;
   replace ContentFolder from IndexItem /
      posthtml = html('posthtml flyover')
      prehtml = html('prehtml flyover bullet')
      listentryanchor = off;
   replace IndexProcName from Index /
      listentryanchor = off
      bullet = "decimal"
      posthtml = html('posthtml flyover')
      prehtml = html('prehtml flyover')
      posttext = text('suffix1')
      pretext = text('prefix1');
   replace IndexTitle from Index /
      posthtml = html('posthtml flyover line')
      prehtml = html('expandAll');
   replace SysTitleAndFooterContainer from Container /
      posthtml = ""
      prehtml = ""
      font = Fonts('TitleFont2')
      rules = NONE
      frame = VOID
      outputwidth = 100%
      cellpadding = 1
      cellspacing = 1
      borderwidth = 0;
   replace TitleAndNoteContainer from Container /
      posthtml = ""
      prehtml = ""
      rules = NONE
      frame = VOID
      outputwidth = 100%
      cellpadding = 1
      cellspacing = 1
      borderwidth = 0;
   replace TitlesAndFooters from Container /
      font = Fonts('TitleFont2')
      foreground = colors('fg');
   replace BylineContainer from Container /
      rules = NONE
      frame = VOID
      outputwidth = 100%
      cellpadding = 1
      cellspacing = 1
      borderwidth = 0;
   replace SystemTitle from TitlesAndFooters /
      font = Fonts('TitleFont');
   replace SystemFooter from TitlesAndFooters /
      font = Fonts('TitleFont');
   replace Byline from TitlesAndFooters /
      font = fonts('TitleFont')
      foreground = colors('fg2');
   replace ProcTitle from TitlesAndFooters /
      font = fonts('TitleFont2');
   replace Output from Container /
      rules = GROUPS
      frame = BOX
      cellpadding = 7
      cellspacing = 1
      borderwidth = 1;
   replace Table from Output /
      posthtml = ""
      prehtml = "";
   replace Batch from Output
      "Batch (capture) Output style." /
      font = fonts('FixedFont')
      foreground = colors('fg');
   replace Graph from Output;
   replace Note from Container /
      posthtml = ""
      prehtml = "";
   replace NoteBanner from Note /
      font = fonts('StrongFont')
      pretext = text('Note Banner');
   replace NoteContent from Note
      "Controls the contents for NOTE:s." /
      just = L;
   replace NoteContentFixed from NoteContent
      "Controls the contents for NOTE:s. Fixed font." /
      just = L
      font = fonts('FixedFont');
   replace WarnBanner from Note
      "Controls the banner for WARNING:s." /
      pretext = text('Warn Banner');
   replace WarnContent from Note
      "Controls the contents of WARNING:s." /
      just = L;
   replace WarnContentFixed from WarnContent
      "Controls the contents for WARNING:s. Fixed font." /
      font = fonts('FixedFont');
   replace ErrorBanner from Note
      "Controls the banner for ERROR:s." /
      pretext = text('Error Banner');
   replace ErrorContent from Note
      "Controls the contents of ERROR:s." /
      just = L;
   replace ErrorContentFixed from ErrorContent
      "Controls the contents for ERROR:s. Fixed font." /
      font = fonts('FixedFont');
   replace FatalBanner from Note
      "Controls the banner for FATAL:s." /
      pretext = text('Fatal Banner');
   replace FatalContent from Note
      "Controls the contents of FATAL:s." /
      just = L;
   replace FatalContentFixed from FatalContent
      "Controls the contents for FATAL:s. Fixed font." /
      font = fonts('FixedFont');
   replace Data from Cell /
      font = Fonts('DocFont')
      foreground = colors('fg3')
      background = colors('bg3');
   replace DataEmphasis from Data /
      font = fonts('EmphasisFont');
   replace DataEmphasisFixed from DataEmphasis /
      font = fonts('FixedEmphasisFont');
   replace DataStrong from Data /
      font = fonts('StrongFont');
   replace HeadersAndFooters from Cell /
      font = fonts('HeadingFont')
      foreground = colors('fg2')
      background = colors('bg2');
   replace Caption from HeadersAndFooters;
   replace HeaderEmphasis from Header /
      font = fonts('EmphasisFont');
   replace HeaderStrong from Header /
      font = fonts('StrongFont');
   end;
run;
/*****************************************************/
/*                                                   */
/* Part 2. Close the listing output                  */
/* open the html output and define the web pages/    */
/* frames/bodyand use the style                      */
/*                                                   */
/*****************************************************/

ods listing close;
ods html body='pllist.htm' frame='pllfr.htm' page='pllpg.htm'
         (nobot) rs=none style=styles.newdoc;

/*****************************************************/
/*                                                   */
/* Part 3. Run the print procedure using             */
/* STYlES.NEWDOC                                     */
/*                                                   */
/*****************************************************/

ods proclabel 'List of Planets';
proc print data=crr.planets noobs label;
     var id name cat soldist orbper rotper radius mass discov datedisc;
     label ID='ID' name='Name' discov='Discoverer' soldist='Distance from Sun (km)'
	       orbper='Orbital Period (days)' datedisc='Date of Discovery' radius='Radius (km)'
           mass='Mass (kg)' rotper='Rotational Period (days)' cat='Planet Group';
	 format soldist mass e8. orbper radius comma6.;
	 title '';
	 title2 ' ';
	 title3 'The Planets in Our Solar System';
	 footnote;
run;

/*****************************************************/
/*                                                   */
/* Part 4. Run the report procedure using            */
/* STYlES.NEWDOC                                     */
/*                                                   */
/*****************************************************/

ods proclabel 'Report on Planetary Planetary Orbits';
proc report data=crr.planets headline headskip nowd;
     title 'Planetary Orbits';
     column cat name soldist circum;
	define cat / order 'Planetary Group' width=10 center;
	define name / display 'Planet' left;
	define soldist / mean 'Distance from Sun (km)' format=E7. width=9;
	define circum / computed format=E10. 'Circumference of Orbit' width=15;
	compute circum;
	        circum=2*3.14159*soldist.mean;
	endcomp;
	break after cat / ol skip summarize;
run;
ods proclabel 'Report on Planetary Orbital Speeds';
proc report data=crr.planets headline headskip nowd;
     title 'Orbital Speeds';
     column cat name soldist orbper speed;
	define cat / order 'Planetary Group' width=10 center;
	define name / display 'Planet' left;
	define soldist / mean 'Distance from Sun (km)' format=E7. width=13;
	define orbper / mean 'Orbital Period (days)' width=14 format=comma10.2;
	define speed / computed 'Speed in Orbit (km per hr)' width=16 format=comma10.2;
	compute speed;
	        speed=2*3.14159*soldist.mean/(orbper.mean*24);
	endcomp;
	break after cat / ol skip summarize;
run;
ods proclabel 'Report on Planet Densities';
proc report data=crr.planets headline headskip nowd;
     title 'Planet Densities';
     column cat name radius mass density;
	define cat / order 'Planetary Group' width=10 center;
	define name / display 'Planet' left;
	define radius / mean 'Radius of Planet (km)' format=comma10.2 width=14;
	define mass / mean 'Mass of Planet (kg)' format=E7. width=14;
	define density / computed 'Density of Planet (kg per cubic m)' format=E7. width=14;
	compute density;
	        density=mass.mean/(4*3.14159*radius.mean*1000/3);
	endcomp;
	break after cat / ol skip summarize;
run;
ods proclabel 'Report on Planetary Rotational Speeds';
proc report data=crr.planets headline headskip nowd;
     title 'Rotational Speeds';
     column cat name radius rotper speed;
	define cat / order 'Planetary Group' width=10 center;
	define name / display 'Planet' left;
	define radius / mean 'Radius of Planet (km)' format=comma10.2 width=14;
	define rotper / mean 'Rotational Period (days)' format=comma10.2 width=14;
	define speed / computed 'Speed of Rotation (km per hr)' format=comma10.2 width=14;
	compute speed;
	        speed=2*3.14159*radius.mean/(rotper.mean*24);
	endcomp;
	break after cat / ol skip summarize;
run;

/*****************************************************/
/*                                                   */
/* Part 5. Run the sql to create a join              */
/* between the planet and moon tables                */
/* use proc report to print this out                 */
/*                                                   */
/*****************************************************/

proc sql;
     create table moon_planet as 
            select p.id, p.name label='Planet Name', m.mname label='Moon Name', 
            m.soldist label='Distance from Planet' format=comma14.,
            m.orbper label='Orbital Period' format=comma5.,
            m.radius/p.radius label='Relative Size' format=E7. 
            from crr.planets p, crr.moon m
	       where p.pid=m.pid order by p.id, m.soldist;
ods proclabel 'Planets and Their Moons';
title 'Planets and Their Moons';
proc report data=moon_planet headline headskip nowd;
     column id name mname soldist orbper _tema005;
	define id / order 'Planet ID' width=10 center format=2.;
	define name / order 'Planet Name';
     define mname / 'Moon Name'; 
     define soldist / 'Distance from Planet' format=comma14.;
     define orbper / 'Orbital Period' format=comma6. width=8;
     define _tema005 / 'Relative Size' format=7.6 width=8;
run;


/*****************************************************/
/*                                                   */
/* Part 6. Close the html and run two data           */
/* steps. The first will update the page frame       */
/* and the second will add source code to the body   */
/*                                                   */
/*****************************************************/

ods html close;
/* Modify the table of contents */
data _null_;
    infile 'pllpg2.htm' end=no_more;
    file 'pllpg.htm' mod;
    input;
    put _infile_;
    if no_more then put '';
run;
/* List the program with the pages */
data _null_;
    infile 'pllist.sas' end=no_more;
    file 'pllist.htm' mod;
    input;
    if _n_=1 then do;
       put '
';
       put '';
    end;
    put _infile_;
    if no_more then put '
';
run;
ods listing;